;lccbuildlib.as

#include "anthspex.as"

	sdim buf,32000
	sdim dir,260
	sdim lcc,260
	sdim build,260
	sdim libdir,260
	sdim s,260

	title "lcc-win32 buildlib"
	w=320: h=480
	buffer 2,w,h
	screen 0,w,h,,dispx-w/2,dispy-h-30/2: gsel 0,1
	font "ＭＳ ゴシック",16
	hh=h-32
	color 191,191,191: boxf 0,hh,w,h
	boxx=32: boxy=hh+8: boxw=w-64: boxh=16
	color 255,255,255: boxf boxx,boxy,boxx+boxw,boxy+boxh
	getdir "lcc-win32のフォルダを指定してください。": c=stat: lcc=refstr
	if c==1: end
	if c: dialog "getdir error. stat="+c: end
	lcc+="\\"
	build=lcc+"bin\\buildlib.exe"
	exist build: if strsize<0: dialog build+"が見つかりません。": end
	dir=lcc+"buildlib\\"
	dirlist buf,dir+"*.exp",1
	strlen len,buf
	libdir=lcc+"lib\\"
	notesel buf: notemax num
	xx=boxx: num1=num-1
	repeat num
		color 0,0,255: x=cnt*boxw/num1+boxx: boxf xx,boxy,x,boxy+boxh: xx=x
		noteget lbuf,cnt
		if lbuf=="cap.exp.exp": continue
		lib=lbuf
		lastchar p,lib,'.': p++
		strput lib,"lib",p,3
		exist dir+lib
		if strsize<0 {
			exist libdir+lib
			if strsize<0 {
				if y>=hh {
					;スクロール
					gsel 2: pos 0,0: gcopy 0,0,0,w,hh
					gsel 0: pos 0,0: gcopy 2,0,16,w,hh-16
					color 255,255,255: boxf 0,hh-16,w-1,hh-1
					y=hh-16
				}
				if noinitflg {
					;ウィンドウが表示されるのを待つ
					gettick start
					repeat: wait 1
						chkwin "buildlib": if stat==0: break
						gettick now
						if now-start>5000: break
					loop
					;ウィンドウが消えるのを待つ
					repeat: wait 1
						chkwin "buildlib": if stat: break
					loop
				}
				pos 0,y: color: mes lbuf
				exec build+" "+dir+lbuf,2
				if y<hh: y+=16
				noinitflg=1
			}
		}
	loop
	;buildlib\*.libをlib\*.libにコピー
	repeat	;１回だと最後に作ったファイルをとりこぼす。
		dirlist buf,dir+"*.lib",1: num=stat
		if num<1: break
		notesel buf
		repeat num
			noteget lbuf,cnt
			s=dir+lbuf
			rename s,libdir+lbuf
			if stat: dialog "rename error("+s+"\n→"+libdir+lbuf+").": end
		loop
	loop
end