;３回戦ジャンケン
;勝敗判定や１回ごとの勝敗の記憶、最終的な勝敗判定のサンプルです。
;Exforce.dllが必要ですが、ボタンの無効化に使っているだけなので、
;6行と48行をコメントにすれば、なくても動きます。

#include "Exforce.as"
    dim table,3,3                   ;勝敗判定表
    table=0,1,2, 2,0,1, 1,2,0
    ;以下と同じ
    ;table.0.0=0: table.1.0=1: table.2.0=2: table.0.1=2: table.1.1=0: table.2.1=1
    ;table.0.2=1: table.1.2=2: table.2.2=0
    ;「table.コンピュータの手.プレイヤーの手」で結果がわかる
    ;手は　0:グー、1:チョキ、2:パー
    ;結果は　0:引き分け、1:（プレイヤーの）勝ち,2:負け
    dim result,3
    ;「result.0」:引き分け数、「result.1」:勝ち数、「result.2」:負け数
    sdim jan,10,3
    jan="グー","チョキ","パー"
    ;     ↑jan.0 ↑jan.1 ↑jan.2
    sdim msg,20,3
    msg="引き分けです","あなたの勝ちです","あなたの負けです"
    randomize                       ;乱数初期化
*l_start
    n=1                             ;回数
    repeat 3: result.cnt=0: loop    ;結果のクリア
*l_loop
    cls
    mes "第"+n+"回戦"
    button "グー",*l_goo
    button "チョキ",*l_choki
    button "パー",*l_par
    ;コンピュータの手
    rnd com,3                       ;comに０〜２の乱数を代入
stop

*l_goo
    play=0
    goto *l_result

*l_choki
    play=1
    goto *l_result

*l_par
    play=2

*l_result
    repeat 3: enable cnt,0: loop            ;じゃんけんボタンの無効化
    mes "コンピュータは"+jan.com
    mes "あなたは"+jan.play
    c=table.com.play                        ;結果
    result.c++                              ;勝敗を更新(result.c=result.c+1)
    mes msg.c                               ;結果表示
    mes "あなたの"+result.1+"勝"+result.2+"敗"+result.0+"引分"
    if n>2 {
                if result.1>result.2 { total=1 }
        else {  if result.1<result.2 { total=2 }
        else                         { total=0 } }
        mes "3回戦トータルで"+msg.total
    }
    button "次",*l_next
stop

*l_next
    n++                                     ;回数を更新
    if n<4: goto *l_loop
goto *l_start